Подводные камни при работе с исключениями в Delphi: Raise Exception, AcquireExceptionObject, исключения операционной системы

    Интересно, на сколько читатель уверен в своих знаниях подводных камней в работе с исключениями в Delphi.  Я решил подготовить три наиболее часто встречаемых ошибки в  рабочем проекте. Надо признаться, некоторые моменты меня удивили. В том числе и ответ на вопрос «в какой момент удаляются объекты исключений».
    Каждый может проверить свои познания подводных камней.  В листинге ниже приведены три метода Error#, каждый из которых ведет к определенной проблеме.
Пояснения я приведу вслед за кодом.

procedure  RaiseOSException;
var
res: integer;
zero: integer;
begin
zero := 0;
res := 5 div zero;
end;

function FormatException(E:Exception): Exception;
begin
if not (E is EMyException) then
result := EMyException.Create(E.Message)
else
begin
E.message := Format('Ошибка обработки исключения: %s', [E.Message]);
result := E;
endl
end;


procedure Error1;
begin
try
RaiseOSException;
except
on E: Exception do
begin
E.Message := Format('Заворачиваем в свой текст: %s', [E.Message]);
Raise;
end;
end;
end;

procedure Error2;
begin
try
raise EMyException.Create('Alarm!!111');
except
on E: Exception do
begin
Raise FormatException(E);
end;
end;
end;

procedure Error3;
begin
try
raise Exception.Create('Alarm!!111');;
except
Raise FormatException(AcquireExceptionObject);
end;
end;

Ответы:

  • Error1 — потеря изменений в сообщение исключения;
  • Error2 — Ошибка Access Violation
  • Error3 — Утечка памяти
Разберем каждый случай более детально:

Потеря сообщений

    В методе Error1 мы изменяем текст исходного сообщения и возбуждаем исключение вновь. Но в диалоге исключения мы не увидим текста с «Заворачиваем в свой текст: %s».
    При возбуждение внешнего исключения Delphi заворачивает его в обертку — собственное исключения и дает обработать в блоке except..end.  Далее, в вызове Raise вызывается System._RaiseAgain в котором происходит удаление объекта делфового исключения(в котором мы и сделали изменение данных поля Message), а дальше возбуждается исходное внешнее исключение  которое ничего не знает про наш новый текст сообщения. 
    Более подробно можно найти описание на stackoverflow.

Ошибка Access Violation (Или «в какой момент удаляются объекты исключений»)


   В методе Error2 мы поймали исключение, хотим отформатировать его текст и пробросить дальше. Однако это приведет к проблеме.  
   Проблема  случая из метода Error2 заключается в том, что Delphi попытается дважды удалить один и тот же объект исключения. Первый раз Raise FormatException(E),  второй раз скорее всего где нибудь в TApplication, в завершения цикла обработки исключений. Ответ находится в System._HandleAnyException в которой каждый сможет найти комментарий:

 { we come here if an exception handler has thrown yet another exception }
        { we need to destroy the exception object and pop the raise list. }

   Синтаксис «Raise Argument: Exception;» подразумевает что мы пытаемся возбудить другой объект исключения, а не тот, что находится сейчас на вершине стека возбужденных исключений. Для этого вычищаем объект исключения, что находится на вершине стека и вталкиваем в стек его новый объект. Проблема заключается в том, что удаляемый и вталкиваемый объект являются одним и тем же объектом. 
  Единственное место, где в документации Embarcadero явно говориться, что так делать нельзя нашел в статье Handling exceptions in Delphi
   Правильно выполнить вызов raise без аргументов(«Raise;»), либо использовать метод AcquireExceptionObject. О нем ниже.

Утечка памяти


    В Error3 мы вместо пойманного исключения стандартного класса создаем собственное исключение, которое может более точно сообщить о проблеме при обработке в вызывающем коде. Нюанс заключается в том, что исходный  объект исключения получаем через AcquireExceptionObject. Данный метод может оказаться незаменим, например если мы хотим передать исключение из одного потока в другой. AcquireExceptionObject возлагает на нас ответственность за дальнейшее освобождения памяти полученного объекта исключения, а Delphi тем временем «умывает руки».
Справка Delphi сообщает, что за методом  AcquireExceptionObject должен следовать ReleaseExceptionObject который уменьшает счетчик ссылок на фрейм исключения(структура в rtl описывающая исключение). Получается, что  в Error3 мы забыли вызвать метод ReleaseExceptionObject? Нет. Вызов ReleaseExceptionObject нам ничем не поможет: объект  утечет в любом случае.
   В действительности счет ссылок и ReleaseExceptionObject  актуальны только для Linux. В модуле System есть объявление типа TRaiseFrame — фрейма исключений, в случае компиляции под Windows счетчик ссылок не предусмотрен. Вот текст метода:

function AcquireExceptionObject: Pointer;
begin
if RaiseListPtr <> nil then
begin
Result := PRaiseFrame(RaiseListPtr)^.ExceptObject;
PRaiseFrame(RaiseListPtr)^.ExceptObject := nil;
end
else
Result := nil;
end;

Метод AcquireExceptionObject «забывает» ссылку на объект исключения во фрейме исключения. А при стандартном попытке удаление исключения  ничего не произойдет, так как предусмотрена проверка на nil в деструкторе объекта:

procedure TObject.Free;
begin
if Self <> nil then
Destroy;
end;

Именно по этому вызов из проблемы которая описана выше не приведет к AV:
except

  E := AcquireExceptionObject;
Raise E; // В данном случае это правильный код
end;

А для метода test3 наиболее правильным будет решение отказаться от AcquireExceptionObject, и получать объект используя синтаксис On E: Exception do. Но все же, если удобнее использовать AcquireExceptionObject, то за ним должен следовать Raise Argument;  либо явный вызов деструктора:

procedure Error3;
var
e : Exception;
begin
try
raise Exception.Create('Alarm!!111');;
except
e := AcquireExceptionObject;
try
Raise FormatException(e);
finally
FreeAndNil(e);
end;
end;
end;

Более подробно, про то, что справка иногда обманывает qc.embarcadero.com

Подводя итог, как делать нельзя:

//AV

On E: Exception do
raise E;
//Утечка
E := AcquireExceptionObject;
raise EMyException.Create(E.Message);
//Утечка
E := AcquireExceptionObject;
try
Foo(E);
finally
ReleaseExceptionObject(E); //Вызов метода бессмысленнен
end;

Читать на сайте автора.

Variant := TObject.Create ?

  Думаю многие сталкивались с тем, что иногда требуется в variant передавать blob, ну или TObject. В таких языках как Java и C# все проще, элементарные типы являются объектами ну или умеют упаковываться из значимых типов в объекты. Для всех типов в языке есть базовый тип. В Delphi же, когда тип на этапе компиляции не известен единственным универсальным решением является использование variant. 
  Но не все так гладко, тип Variant предназначен только для хранения простых типов и указатель на объект в него не поместить не используя грязных хаков. Хотя сам RTL ими так и кишит. Так для хранения ftBlob в variant используется строка. 
На самом деле есть «законный»  механизм как через Variant передавать любые данные, в том числе и объекты. Для этого есть базовый класс TCustomVariantType, на основе которого можно определить свой тип который можно будет передавать как Variant, перекрыть в нем бинарные арифметические  и логические операции. Т.е. реализовать например свое сравнению и сложение для экземпляров типа. 
Но вот тут мы подходим к самому интересному, в FireMonkey появились методы по преобразованию variant к TObject и обратно:

function VarIsObject(Value: Variant): Boolean;
function ObjectToVariant(const AObject: TObject): Variant;
function VariantToObject(const Value: Variant): TObject;
Выглядит интригующе, неправда ли? 
Но что внутри?
Совершенно обычный хак, все опять сделано через строки:
function ObjectToVariant(const AObject: TObject): Variant;
begin
Result := 'vgobj' + IntToStr(Integer(Pointer(AObject)));
end;

function VariantToObject(const Value: Variant): TObject;
var
S: string;
begin
S := Value;
{$IFDEF FPCCOMP}
if (S <> '') and (Pos(WideString('vgobj'), S) = 1) then
{$ELSE}
if (S <> '') and (Pos('vgobj', S) = 1) then
{$ENDIF}
Result := TObject(Pointer(StrToInt(Copy(S, 6, 10))))
else
Result := nil;
end;

…и расположено это все не в модули System или Variants, а в Types. Никакой поддержки на уровне компилятора нет. Т.е. все еще нельзя писать так

var 
v: Variant;
begin
v := TMyClass.Create();
end;

  Почему бы Embarcadero уже не реализовать нормальную поддержку объектов в variant, ну или хотя бы сделать на основе TCustomVariantType. Непонятно. Притом, что есть и наследники от него TInvokeableVariantType и TPublishableVariantType.


  Возможно, все ради совместимости с COM Variant, не хотят далеко от него уходить и пытаются сохранить Variant для типов передающихся по значению. Или, возможно, методы VariantToObject и ObjectToVariant были реализованы Евгением Крюковым KSDev, а в Embarcadero не стали ничего переделывать, работает и на том спасибо.


Читать на сайте автора.

Чтение в FinalBuilder VersionInfo из проекта Delphi 7

  С удивлением обнаружил, что на многих форумах у коллег возникают проблемы как при автоматической сборке проекта через FinalBuilder автоматизировать изменение VersionInfo.
  Для начала внесем ясность где настройки содержаться.
  В Делфи 7 проектах для настроек используется файл .dof, в этот файл IDE сохраняет все настройки проекта. При компиляции на основе этого файла формируется .rc файл — скрипт который уже поступает на вход компилятора ресурсов, на выходе который возвращает .res файл. .res файл будет содержать VersionInfo  и информацию об иконки исполняемого файла. При компиляции dcc( Delphi Pascal Compiler) включает ресурсы в исполняемое приложение (если они указаны в модулях {$R *.res}). Некоторые настройки могут перекрываться .cfg   файлом. cfg файл создается при каждом сохранение проекта из IDE. Dcc проверяет наличие .cfg файла c именем совпадающем с названием проекта и если файл обнаружен использует настройки из него при компиляции. В своем проекте Finalbuilder’а я удаляю перед сборкой этот файл.
  Вернемся к нашим баранам, .dof файл в действительности имеет формат ini файла. А для работы с ini файлами в FinalBuilder есть действия (action)  «Read Ini File» и «Write Ini File». С помощью их мы можем прочесть любые значения из VersionInfo, Version Info Keys (и других) и записать обратно до вызова dcc.
Пример настройки действия чтения MajorVer значения. 

  Но что бы такая схема заработало неодходимо в действие Build Delphi Win32 Project на закладке Project отменить «Load Settings from project File» и «Version Info»:


В этом случае при сборке будет использоваться .dof файл.

Читать на сайте автора.

IE9 in edit Mode & TWebBrowser = EZeroDivide

  В начале предисловия предисловие

  Приветствую тебя случайный гость. Данный блог давно задумывался, но все что то мешало, то не было темы с которой можно начать, то природная лень брала верх над намеченным. Основная цель преследуемая блогом это упорядочивание знаний, закрепление опыта, развитие навыков изложения материала, вообщем как и у всех, т.е. для себя. Если такие цели, то «какого черта» простите ждать? Садимся и пишем! Так и появилась первая запись в этом блоге, посмотрим что в дальнейшем из этого может выйти.

  На этой недели вылезла не самая тривиальная ошибка которой и хочу поделиться в первую очередь с собой=) и с возможным читателем. 

  В программной системе на моей текущей работе для отображения HTML разметки используется компонент TWebBrowser, который как известно является оберткой для COM ядра Internet Explorer’а. С недавних пор у некоторых клиентов нашего приложения  фрейм содержащий TWebBrowser стал валиться c исключением EZeroDivide — ошибка деления на ноль. В дальнейшем выяснилось, что ошибка имеет место лишь при установленном IE9 находящемся в режиме редактирования в OS Windows 7 64bit. И как только пользователь касался полосы прокрутки всплывало исключение. 
Место генерации исключения было не в Delphi обертке и находилось где то внутри IE.  Гугление показало, что я не одинок в своей проблеме, и нас как минимум трое=). Удалось установить и причину проблемы.   
  Все дело в том, что по умолчанию в MSVC и библиотеках написанных на нем при выполнение операций в FPU не возбуждаются исключения на ошибки, а возвращает значения NaN, +INF, -INF.  За настройку данного поведения в FPU отвечает так называемый регистр управляющее слово — Control Word (CW).Кроме того, через него можно задать и другие параметры влияющие на вычисление операций над числами с плавающей запятой, например точность. 
Для решения проблемы достаточно установить нужную маску в данный регистр перед созданием TWebBrowser и восстановить значение регистра после закрытия. Это может выглядеть как то так:

var 
CW: word;

procedure TForm1.FormCreate(Sender: TObject);
begin
CW := Get8087CW(); // Запоминаем предыдущее состояние регистра
System.Set8087CW($133f); // Выключаем исключения
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
System.Set8087CW(CW); // Восстанавливаем предыдущее значение регистра
end;


  Но данный способ приемлем если у вас форма с TWebBrowser открыта модально или приложение не большое. В случае же если приложение MDI, большое и пользователь может динамически выполнять скрипты, то ни как не хотелось бы отключать генерацию исключений на все время работы приложения. Но как сделать так, что бы исключения были выключены только для TWebBrowser? 
К счастью для меня TWebBrowser используется у нас для отображения статической HTML разметки и проблема была замечены только когда пользователь трогал полосу прокрутки, потому было решено менять значение управляющего регистра только когда мышь появляется над TWebBrowser и восстанавливать обратно, когда покидает границы компонента.


TEventObject = class(TInterfacedObject,IDispatch)
private
FOnEvent: TProc;
protected
function GetTypeInfoCount(out Count: Integer): HResult; stdcall;
function GetTypeInfo(Index, LocaleID: Integer; out TypeInfo): HResult; stdcall;
function GetIDsOfNames(const IID: TGUID; Names: Pointer;
NameCount, LocaleID: Integer; DispIDs: Pointer): HResult; stdcall;
function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer;
Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult; stdcall;
public
constructor Create(const OnEvent: TProc);
property OnEvent: TProc read FOnEvent write FOnEvent;
end;

var
webBrowser: IWebBrowser;
iDocument2: IHTMLDocument2;
eoMouseLeave, eoMouseEnter: TEventObject;
iElement2: IHTMLElement2;
j: Integer;
CW: Word;

implementation

function TEventObject.Invoke(DispID: Integer; const IID: TGUID;
LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo,
ArgErr: Pointer): HResult;
begin
if (Dispid = DISPID_VALUE) then
begin
if Assigned(FOnEvent) then
FOnEvent; // Вызываем обработчик события
Result := S_OK;
end
else Result := E_NOTIMPL;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
{Создание объектов обработчиков реализующих IDispatch}
eoMouseEnter := TEventObject.Create(self.OnMouseEnter);
eoMouseLeave := TEventObject.Create(self.OnMouseLeave);
end;

procedure TForm1.WebBrowser1DocumentComplete(Sender: TObject;
const pDisp: IDispatch; var URL: OleVariant);
begin
{Устанавливаем обработчики на события после загрузки страницы}
webBrowser := pDisp as IWebBrowser;
if Assigned(webBrowser.Document) then
begin
iDocument2 := webBrowser.Document as IHTMLDocument2;
iDocument2.DesignMode := 'On';

for j:=0 to iDocument2.All.Length-1 do
begin
iElement2 := iDocument2.All.item(j,EmptyParam) as IHTMLElement2;
iElement2.AttachEvent('onmouseenter', eomouseEnter);
iElement2.AttachEvent('onmouseleave', eoMouseLeave);
end;
end;
end;

procedure TForm1.WebBrowser1BeforeNavigate2(Sender: TObject;
const pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
Headers: OleVariant; var Cancel: WordBool);
begin
{отсоединяем обработчики от событий, перед загрузкой новой страницы}
if Assigned(webBrowser.Document) then
begin
iDocument2 := webBrowser.Document as IHTMLDocument2;
for j:=0 to iDocument2.All.Length-1 do
begin
iElement2:=All.item(i,EmptyParam) as IHTMLElement2;
iElement2.detachEvent('onmouseenter', eoMouseEnter);
iElement2.detachEvent('onmouseleave', eoMouseLeave);
end;
end;
end;


procedure TForm1.OnMouseEnter;
begin
CW := Get8087CW();
System.Set8087CW($133f); // Отключаем исключения
end;

procedure TForm1.OnMouseLeave;
begin
System.Set8087CW(CW); // Восстанавливаем значение регистра
end;


  Здесь мы вешаем обработчики на события OnMouseEnter и OnMouseLeave, т.к. MSDN говорит нам, что события не всплывающие(не проходят по всей иерархии DOM до верхнего уровня), то обработчики устанавливаем на все объекты документа.  В качестве обработчика метод IHTMLDocument.AttachEvent просит объект с IDispatch, для этого реализуем TEventObject. И не забываем, что eoMouseEnter, eoMouseleave надо удалить перед закрытием формы.

Читать на сайте автора.